# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2

inherit eutils versionator flag-o-matic toolchain-funcs

DESCRIPTION="Daemon for Linkstation/Kuro PRO micro controller"
HOMEPAGE="http://buffalo.nas-central.org/download/Users/lb_worm/micro_evtd/micro_evtd"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~arm"
IUSE=""
RESTRICT="mirror"

# tarballs use debian versioning format
MY_PN="micro-evtd"
MY_PVR=$(replace_version_separator 2 '-' )
MY_PV=${MY_PVR/-*/}

S="${WORKDIR}/${MY_PN}-${MY_PV}"

SRC_URI_BASE="mirror://debian/pool/main/${MY_PN:0:1}/${MY_PN}/"
SRC_URI="${SRC_URI_BASE}${MY_PN}_${MY_PV}.orig.tar.gz
		${SRC_URI_BASE}${MY_PN}_${MY_PVR}.debian.tar.gz"

DEPEND=""
RDEPEND=""

src_prepare() {
	EPATCH_SOURCE="${WORKDIR}/debian/patches" EPATCH_SUFFIX="patch" \
	EPATCH_FORCE="yes" EPATCH_EXCLUDE="makefile.patch" epatch
	ln -sf micro-evtd.mak Makefile
}

src_compile() {
	emake SBIN_PREFIX=/usr CC="$(tc-getCC)" CFLAGS="${CFLAGS} -Wall" LDFLAGS="${LDFLAGS}" all || die "emake failed"
	emake SBIN_PREFIX=/usr CC="$(tc-getCC)" CFLAGS="${CFLAGS} -Wall" LDFLAGS="${LDFLAGS}" ts || die "emake failed"
}

src_install() {
	emake SBIN_PREFIX=/usr DESTDIR="${D}" install || die "install failed"
	mv "${D}"/usr/sbin/micro-evtd "${D}"/usr/sbin/micro-evtd.pro
	emake SBIN_PREFIX=/usr DESTDIR="${D}" install.ts || die "install failed"
	mv "${D}"/usr/sbin/micro-evtd "${D}"/usr/sbin/micro-evtd.tera
	newsbin "${FILESDIR}"/micro-evtd.wrapper micro-evtd

	dodoc Changelog README TODO

	newinitd "${FILESDIR}"/micro-evtd-boot.initd-r2 micro-evtd-boot
	newinitd "${FILESDIR}"/micro-evtd-default.initd-r2 micro-evtd
}

