# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/oracle-jre-bin/oracle-jre-bin-1.7.0.2.ebuild,v 1.1 2011/12/18 09:52:17 sera Exp $

EAPI="4"

inherit java-vm-2 eutils prefix versionator

UPDATE="$(get_version_component_range 4)"
UPDATE="${UPDATE#0}"
MY_PV="$(get_version_component_range 2)u${UPDATE}"
S_PV="$(get_version_component_range 1-3)_0${UPDATE}"

BUILD="24"
BUILDDATE="10_aug_2012"
SUFFIX=".tar.gz"
ARMV5_AT="ejre-${MY_PV}-fcs-b${BUILD}-linux-arm-sflt-headless-${BUILDDATE}${SUFFIX}"
ARMV6_AT="ejre-${MY_PV}-fcs-b${BUILD}-linux-arm-vfp-client_headless-${BUILDDATE}${SUFFIX}"
ARMV7_AT="ejre-${MY_PV}-fcs-b${BUILD}-linux-arm-vfp-client_headful-${BUILDDATE}${SUFFIX}"

# This URIs need updating when bumping!
JRE_URI="http://www.oracle.com/technetwork/java/embedded/overview/getstarted/index.html"
JCE_URI="http://www.oracle.com/technetwork/java/javase/downloads/jce-7-download-432124.html"

JCE_DIR="UnlimitedJCEPolicy"
JCE_FILE="${JCE_DIR}JDK7.zip"

DESCRIPTION="Oracle's Java SE Runtime Environment"
HOMEPAGE="http://www.oracle.com/technetwork/java/javase/"
SRC_URI="arm? ( ${ARMV5_AT} ${ARMV6_AT} ${ARMV7_AT} )
	jce? ( ${JCE_FILE} )"

LICENSE="ejre-7"
SLOT="1.7"
KEYWORDS="~arm"
RESTRICT="fetch strip"
IUSE="X alsa jce"

DEPEND="jce? ( app-arch/unzip )"
RDEPEND="${DEPEND}
	X? (
		x11-libs/libXext
		x11-libs/libXi
		x11-libs/libXrender
		x11-libs/libXtst
		x11-libs/libX11
	)
	alsa? ( media-libs/alsa-lib )
	!prefix? ( sys-libs/glibc )"

QA_TEXTRELS_arm="
	opt/${P}/lib/arm/client/libjvm.so
	opt/${P}/lib/arm/server/libjvm.so"

S="${WORKDIR}/ejre${S_PV}"

pkg_nofetch() {
	if use arm; then
		AT="${ARMV5_AT} ${ARMV6_AT} ${ARMV7_AT}"
	fi

	einfo "Please download ${AT} from:"
	einfo "${JRE_URI}"
	einfo "and move it to ${DISTDIR}"

	if use jce; then
		einfo "Also download ${JCE_FILE} from:"
		einfo ${JCE_URI}
		einfo "and move it to ${DISTDIR}"
	fi
}

src_unpack() {
	einfo "Unpacking for arch ${CHOST/-*/}"

	if [[ ${CHOST/-*/} = "armv5tel" ]]; then
		unpack ${ARMV5_AT}
	elif [[ ${CHOST/-*/} = "armv6j" ]]; then
		unpack ${ARMV6_AT}
	elif [[ ${CHOST/-*/} = "armv7a" ]]; then
		unpack ${ARMV7_AT}
	fi
}

src_prepare() {
	if use jce; then
		mv "${WORKDIR}"/${JCE_DIR} "${S}"/lib/security/ || die
	fi
}

src_compile() {
	# This needs to be done before CDS - #215225
	java-vm_set-pax-markings "${S}"

	# see bug #207282
	einfo "Creating the Class Data Sharing archives"
	if use arm; then
		"${S}"/bin/java -client -Xshare:dump || die
	fi
	#"${S}"/bin/java -server -Xshare:dump || die

	# Create files used as storage for system preferences.
	mkdir .systemPrefs || die
	touch .systemPrefs/.system.lock || die
	touch .systemPrefs/.systemRootModFile || die
}

src_install() {
	dodir /opt/${P}
	cp -pPR bin lib "${ED}"/opt/${P} || die

	# Remove empty dirs we might have copied
	#rmdir -v $(find "${ED}" -type d -empty) || die

	dodoc COPYRIGHT README THIRDPARTYLICENSEREADME.txt

	if use jce; then
		dodir /opt/${P}/lib/security/strong-jce
		mv "${ED}"/opt/${P}/lib/security/US_export_policy.jar \
			"${ED}"/opt/${P}/lib/security/strong-jce || die
		mv "${ED}"/opt/${P}/lib/security/local_policy.jar \
			"${ED}"/opt/${P}/lib/security/strong-jce || die
		dosym /opt/${P}/lib/security/${JCE_DIR}/US_export_policy.jar \
			/opt/${P}/lib/security/
		dosym /opt/${P}/lib/security/${JCE_DIR}/local_policy.jar \
			/opt/${P}/lib/security/
	fi

	# bug #56444
	cp "${FILESDIR}"/fontconfig.Gentoo.properties "${T}"/fontconfig.properties || die
	eprefixify "${T}"/fontconfig.properties
	insinto /opt/${P}/lib/
	doins "${T}"/fontconfig.properties

	# bug #388127
	dodir /etc/sandbox.d
	echo 'SANDBOX_PREDICT="/dev/random:/proc/self/coredump_filter"' > "${D}/etc/sandbox.d/20${VMHANDLE}"

	set_java_env
	java-vm_revdep-mask
}
