# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/dietlibc/dietlibc-0.33_pre20110403.ebuild,v 1.7 2012/08/21 03:29:23 ottxor Exp $

EAPI="3"

inherit eutils flag-o-matic toolchain-funcs

MY_PV=${PV/_pre/~cvs}
DEB_PV="4"

DESCRIPTION="A libc optimized for small size"
HOMEPAGE="http://www.fefe.de/dietlibc/"
SRC_URI="https://launchpad.net/ubuntu/+archive/primary/+files/dietlibc_${MY_PV}.orig.tar.gz
	https://launchpad.net/ubuntu/+archive/primary/+files/dietlibc_${MY_PV}-${DEB_PV}.debian.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~arm"
IUSE="debug"

DEPEND=""
RDEPEND=""

S="${WORKDIR}"/dietlibc-${MY_PV}

DIETHOME=/usr/diet

pkg_setup() {
	# Replace sparc64 related C[XX]FLAGS (see bug #45716)
	use sparc && replace-sparc64-flags

	# gcc-hppa suffers support for SSP, compilation will fail
	use hppa && strip-unsupported-flags

	# debug flags
	use debug && append-flags -g

	# Makefile does not append CFLAGS
	append-flags -nostdinc -W -Wall -Wextra -Wchar-subscripts \
		-Wmissing-prototypes -Wmissing-declarations -Wno-switch \
		-Wno-unused -Wredundant-decls -fno-strict-aliasing

	# only use -nopie on archs that support it
	gcc-specs-pie && append-flags -nopie
}

src_prepare() {
	EPATCH_SOURCE="${WORKDIR}/debian/patches" EPATCH_SUFFIX="diff" \
	EPATCH_FORCE="yes" epatch
	ln -sf bin-${ARCH} bin-${CHOST/-*/}
}

src_compile() {
	emake prefix="${EPREFIX}"${DIETHOME} \
		CC="$(tc-getCC)" \
		CFLAGS="${CFLAGS}" \
		STRIP=":" \
		|| die "make failed"
}

src_install() {
	emake prefix="${EPREFIX}"${DIETHOME} \
		DESTDIR="${D}" \
		install-bin \
		install-headers \
		|| die "make install failed"
	# broken so add a workaround
	ln -sf lib-${ARCH} "${D}"/${DIETHOME}/lib-${CHOST/-*/}

	dobin "${ED}"${DIETHOME}/bin/* || die "dobin failed"
	doman "${ED}"${DIETHOME}/man/*/* || die "doman failed"
	rm -r "${ED}"${DIETHOME}/{man,bin}

	dodoc AUTHOR BUGS CAVEAT CHANGES README THANKS TODO PORTING
}
